I haven't had time to write a full featured program to control the icicle but the prototype sketch below provides an icicle that drips every 8 seconds then goes into 'Power Down Sleep' mode in between drips. You can use and modify this sketch whichever way you want.

The enterSleep() function puts the Pro-Mini to sleep. You must give it a parameter which matches one of the cases in the switch statement. I said it was a prototype. The burst() and burstPair() functions illuminate one or two LEDs by enabling the LEDs then sending a square wave to the voltage booster. go_sleep() just calls the enterSleep() function and the loop() function sequences the flashing.

Have a good holiday.

//////////////////////////////////////////////////////////////////////////////
// Icicle
// Flashes 6 LEDs in sequence to mimic an icicle drip.
//////////////////////////////////////////////////////////////////////////////

#include <avr/wdt.h>            // library for default watchdog functions
#include <avr/interrupt.h>      // library for interrupts handling
#include <avr/sleep.h>
#include <avr/power.h>
#include <avr/wdt.h>

#define HIGH_OUT 2
#define CAPACITOR 3
#define LED_0 4
#define LED_1 5
#define LED_2 6
#define LED_3 7
#define LED_4 8
#define LED_5 9

volatile int f_wdt=1;

//////////////////////////////////////////////////////////
// ISR() - Executes when the watchdog times out.
//////////////////////////////////////////////////////////
ISR(WDT_vect)
{
  sleep_disable();

if(f_wdt == 0)
  {
    f_wdt=1;
  }
  else
  {
    //Serial.println("WDT Overrun!!!");
  }
}

//////////////////////////////////////////////////////////
// enterSleep() - goes to sleep.
//////////////////////////////////////////////////////////
void enterSleep(int sleep_time)
{
  byte adcsra_safe = ADCSRA;              // Save the ADC control and status register
  unsigned int _wdtcsr;
  
  ADCSRA = 0;                            // Turn off the ADC module  
  set_sleep_mode(SLEEP_MODE_PWR_DOWN);   // Lowest power consumption.

// Clear the reset flag. 
  MCUSR &= ~(1<<WDRF);
  
  // Set new watchdog timeout prescaler value
  // reminder of the definitions for the time before firing
  // delay interval patterns:
  //  16 ms:     0b000000
  //  500 ms:    0b000101
  //  1 second:  0b000110
  //  2 seconds: 0b000111
  //  4 seconds: 0b100000
  //  8 seconds: 0b100001

switch(sleep_time)
  {
      case 16:
        _wdtcsr = 0;
        break;
      case 32:
        _wdtcsr = 1<<WDP0;
        break;
      case 64:
        _wdtcsr = 1<<WDP1;
        break;
      case 128:
        _wdtcsr = 1<<WDP0 | 1<<WDP1;
        break;
      case 250:
        _wdtcsr = 1<<WDP2;
        break;
      case 500:
        _wdtcsr = 1<<WDP0 | 1<<WDP2;
        break;
      case 1000:
        _wdtcsr = 1<<WDP1 | 1<<WDP2;
        break;
      case 2000:
        _wdtcsr = 1<<WDP0 | 1<<WDP1 | 1<<WDP2;
        break;
      case 4000:
        _wdtcsr = 1<<WDP3;
        break;
      case 8000:
      default:
        _wdtcsr = 1<<WDP0 | 1<<WDP3;
        break;
  }

WDTCSR |= (1<<WDCE) | (1<<WDE);               // Enable configuration changes
  WDTCSR = _wdtcsr;                             // Set the prescaler
  
  // Enable the WD interrupt (note no reset).
  WDTCSR |= _BV(WDIE);
  
  sleep_enable();
  
  // Turn off brown-out enable in software
  // The BOD should be permanently turned off by programming fuses
  // but we disable it here just to make sure.  
  cli();
  MCUCR = bit (BODS) | bit (BODSE);           // Turn on brown-out enable select
  MCUCR = bit (BODS);                         // This must be done within 4 clock cycles of above
  sei();                                      // Guarantees next instruction executed
  
  /* Now enter sleep mode. */
  sleep_mode();
  
  /* The program will continue from here after the WDT timeout*/
  sleep_disable(); /* First thing to do is disable sleep. */ 
  ADCSRA = adcsra_safe;            // Restore ADCSRA
  
}

//////////////////////////////////////////////////////////
// led_disable() - Disables an LED by sending its pin high.
//////////////////////////////////////////////////////////
void led_disable(int led)
{
  pinMode(led, INPUT);
  digitalWrite(led, HIGH);
}

//////////////////////////////////////////////////////////
// led_enable() - Enables an LED by sending its pin low.
// This allows the voltage from the boost circuit to illuminate it.
//////////////////////////////////////////////////////////
void led_enable(int led)
{
  pinMode(led, OUTPUT);
  digitalWrite(led, LOW);
}

//////////////////////////////////////////////////////////
// setup() - Initialises and flashes the buit in LED.
//////////////////////////////////////////////////////////
void setup() 
{
  // initialize digital pin LED_BUILTIN as an output.
  MCUSR = 0;
  wdt_disable();
  WDTCSR = 0;                       // Reset WD control register
  sleep_disable();                  // First thing to do is disable sleep.
  pinMode(LED_BUILTIN, OUTPUT);
  pinMode(HIGH_OUT, OUTPUT);
  pinMode(CAPACITOR, OUTPUT);

digitalWrite(LED_BUILTIN, HIGH);
  delay(500);
  digitalWrite(LED_BUILTIN, LOW);
}

//////////////////////////////////////////////////////////
// burst() - Illuminate an LED by first enabling it then 
// sending a burst of pulses to the voltage boost circuit. 
//////////////////////////////////////////////////////////
void burst(int led)
{
  long int i;
  led_enable(led);
  pinMode(HIGH_OUT, OUTPUT);
  pinMode(CAPACITOR, OUTPUT);

digitalWrite(HIGH_OUT, HIGH);
  for (i = 0; i < 1200; i++)
  {
    digitalWrite(CAPACITOR, HIGH);
    digitalWrite(CAPACITOR, LOW);
  }

pinMode(HIGH_OUT, INPUT);
  pinMode(CAPACITOR, INPUT);
  led_disable(led);
}

//////////////////////////////////////////////////////////
// burstPair() - Illuminate two LEDs by sending a burst of pulses
// to each LED. This is used to give the illusion of flow between
// one LED to the next. 
//////////////////////////////////////////////////////////
void burstPair(int led1, int led2)
{
  long int i;
  pinMode(HIGH_OUT, OUTPUT);
  pinMode(CAPACITOR, OUTPUT);

digitalWrite(HIGH_OUT, HIGH);
  for (i = 0; i < 300; i++)
  {
    led_enable(led1);
    digitalWrite(CAPACITOR, HIGH);
    digitalWrite(CAPACITOR, LOW);
    led_disable(led1);
    led_enable(led2);
    digitalWrite(CAPACITOR, HIGH);
    digitalWrite(CAPACITOR, LOW);
    led_disable(led2);
  }

pinMode(HIGH_OUT, INPUT);
  pinMode(CAPACITOR, INPUT);
}

//////////////////////////////////////////////////////////
// go_sleep() - Calls the sleeping function.
//////////////////////////////////////////////////////////
void go_sleep(int duration) 
{
  if(f_wdt == 1)
  {
    f_wdt = 0;                  // Don't forget to clear the flag.
    enterSleep(duration);
  }
  else
  {
    /* Do nothing. */
  }
}

//////////////////////////////////////////////////////////
// loop() - Controls how the LEDs are illuminated and when the
// app sleeps.
//////////////////////////////////////////////////////////
void loop() 
{
  burst(LED_0);
  burstPair(LED_0, LED_1);
  burst(LED_1);
  burstPair(LED_1, LED_2);
  burst(LED_2);
  burstPair(LED_2, LED_3);
  burst(LED_3);
  burstPair(LED_3, LED_4);
  burst(LED_4);
  burstPair(LED_4, LED_5);
  burst(LED_5);
  go_sleep(8000);
}

<< Christmas Lights Icicle Button Battery Board

Now subscribe to our newsletter and don't miss a thing

Tagged: Arduino Pro Mini Christmas Low Power LED Lights

Comments

No comments yet.

Add Comment

* Required information

Name: *

Email: * (will not be published)

Website:

Country:

Rating:

Comment: *

Captcha: * Captcha

Enter code:

Notify me of new comments via email.

Remember my form details on this computer.

I have read and understand the privacy policy. *

I have read and agree to the terms and conditions. *

Arduino Christmas Icicle Lights - Ultra Low Power Pro-Mini

Arduino Pro-Mini Carrier with ISP Programming

Arduino Pro-Mini ISP Programmer Using A UNO

Voltage Multiplier - Arduino Low Voltage LED Driver

Serial Voltage Level Converter - Arduino

Servo Motor Control Systems

LED Bar Graph With Transistors

Sony Vaio Fan replacement

Dremel Multitool - How To Use

Sound Card Oscilloscope - Build Better Electronics Projects

Easy Project Power Supply For Raspberry Pi & Beaglebone

Raspberry Pi UPS

Long Time Delays With A 555 Chip

A Power Off Delay For Computer Shutdown

How To Make A Free Sound Card PC Oscilloscope

Sound Card Oscilloscope Software

Raspberry Pi Beginner Projects: Setting Up

Getting Started With Electronics Review

How To Measure Output Impedance The Easy Way

Simple Transistor As An Amplifier

Sound Card Oscilloscope and Multivibrators

Arduino Tachometer

Arduino Motion Detector

Power Dissipated By Resistor: How To Blow Up A Circuit

Darlington Transistor Touch Switch Simple Science Project

Arduino Distance Sensor Part 2

Arduino Distance Sensor

Magnifying Desk Lamp Best Tool To Buy

Electronic Engineering Construction Kits For Kids And Parents

Transistor Touch Switch Simple Science Project

Science Projects For Kids First Electric Circuit

Arduino Safety Cut Out Senses Jams

Snap Circuits Extreme SC-750 Videos

Arduino Programming the HC-SR04 with Interrupts

Arduino Timer Interrupt Example

Arduino Uno Projects And Software

What Does A Resistor Do?

Hobby Electronics Toys That Turn Kids Into Engineers

How To Build An Astable Multivibrator Circuit Without Solder

Soldering Is Easy

Solderless Breadboards For Building Electronic Circuits

Electronics Tool Kit Essentials

About Electronics and How I Became An Engineer

Click here for a free subscription to "HDE" our site newsletter.

Pocket-Sized Digital Oscilloscope ARM DSO Nano DSO201

Hantek PC Based USB Digital Storage Oscilloscope 6022BE, 20Mhz Bandwidth

The Official Arduino Starter Kit

Arduino Workshop

Pocket-size analog multimeter, YG188

Oscilloscopes at Amazon

Arduino at Amazon

Components at Amazon

Kits at Amazon

Raspberry Pi at Amazon

Tools at Amazon

You should assume that there is an affiliate relationship and/or another material connection to the providers of goods and services linked to on this page and that we may be compensated when you purchase from a provider. Homediyelectronics.com is a participant in the Amazon Services LLC Associates Program and the Amazon EU Associates Programme, an affiliate advertising program designed to provide a means for sites to earn advertising fees by advertising and linking to amazon.com and amazon.co.uk.